《VBA高级应用30例》（版权10178985），是我推出的第十套教程，教程是专门针对高级学员在学习VBA过程中提高路途上的案例展开，这套教程案例与理论结合，紧贴“实战”，并做“战术总结”，以便大家能很好的应用。教程的目的是要求大家在实际工作中分发VBA程序，写好的程序可以升级。

本套教程共三册三十个专题，VBA高级应用30例：Ribbon加载后onLoad回调

【分享成果，随喜正能量】 各自修行，各自好；各自因果，各自了。成年人最大的清醒，就是管好自己，不渡他人，克制自己纠正他人的欲望。很多事情就算你是对的，也无需证明别人是错的。。

应用1 在EXCEL中构建加载项

7 代码功能实现

1) Ribbon load

在打开这个加载项时候，为了能够告诉Excel它需要更新功能区，我们需要一个指向功能区对象的指针。该指针在onLoad回调中传递给我们。因此，让我们添加一个模块级对象变量并为其指定Ribbon对象：

Sub mynzSheetToolscustomUI_onLoad(ribbon As IRibbonUI)

Set moRibbon = ribbon

ThisWorkbook.Worksheets("Sheet1").Range("RibbonPointer").Value = "'" & ObjPtr(moRibbon)

End Sub

这里，VBA会记住Ribbon对象，因此我们可以要求它从代码中刷新。打开Excel文件并启用宏时，onLoad是第一个被调用的回调。

2）使用工作表选项卡名称填充下拉列表

接下来发生的事情是下拉列表请求它需要加载的项目数。这是在mynzSheetToolsbtnSheets getItemCount回调中完成的：

'Callback for mynzSheetToolsbtnSheets getItemCount

Sub mynzSheetToolsbtnSheets_Count(control As IRibbonControl, ByRef returnedVal)

Dim lCt As Long

Dim oSh As Object

For Each oSh In Sheets

If oSh.Visible = xlSheetVisible Then lCt = lCt + 1

Next

returnedVal = lCt

End Sub

该过程只计算活动工作簿中可见工作表的数量，并将该数量传递给returnedVal变量，该变量将传递回Excel。

3）触发下一个回调，它将获取实际的工作表名称

Public Sub mynzSheetToolsbtnSheets_getItemLabel(control As IRibbonControl, Index As Integer, ByRef returnedVal)

Dim lCt As Long

Dim oSh As Object

For Each oSh In Sheets

If oSh.Visible = xlSheetVisible Then lCt = lCt + 1

If lCt = Index + 1 Then

returnedVal = oSh.Name

Exit For

End If

Next

End Sub

调用此回调的次数与在上一次回调中传递的工作表数相同。索引从零开始，所以你必须注意返回到它的内容。因此，对sub的每次调用都要求一个工作表名称。

4）填充下拉列表时，我们希望它显示活动工作表的名称,由此回调处理.

'Callback for mynzSheetToolsbtnSheets getSelectedItemIndex

Sub mynzSheetToolsbtnSheets_getSelectedItemIndex(control As IRibbonControl, ByRef returnedVal)

Dim lCt As Long

Dim oSh As Object

For Each oSh In Sheets

If oSh.Visible = xlSheetVisible Then lCt = lCt + 1

If oSh.Name = ActiveSheet.Name Then

returnedVal = lCt - 1

Exit For

End If

Next

End Sub

5）最后，如果我们从下拉列表中选择一张工作表，我们希望它将我们带到那里

Sub mynzSheetToolsbtnSheets_Click(control As IRibbonControl, id As String, Index As Integer)

Dim lCt As Long

Dim oSh As Object

For Each oSh In Sheets

If oSh.Visible = xlSheetVisible Then lCt = lCt + 1

If lCt = Index + 1 Then

oSh.Activate

Exit Sub

End If

Next

End Sub

刚才讲过下拉索引从零开始，注意Excel的工作表索引从1开始。

6）更新TOC工作表

我们设计一个空回调函数，因此让我们调用在开始时设计的宏：

Sub mynzSheetToolsbtnInsertTOC(control As IRibbonControl)

UpdateTOC

End Sub

（待续）

我20多年的VBA实践经验，全部浓缩在下面的各个教程中：